# Copyright 2026 Shin'ya Minazuki
# This file was not copied from ::gentoo, this is written from scratch
EAPI=8

PYTHON_COMPAT=( python3_{11..13} )
inherit flag-o-matic python-single-r1 meson

DESCRIPTION="A console based XMPP client inspired by Irssi"
HOMEPAGE="https://profanity-im.github.io https://github.com/profanity-im/profanity"
SRC_URI="https://profanity-im.github.io/tarballs/${P}.tar.xz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"

# At the top, required run-time dependencies
# At the bottom, all optional dependencies (with USE flags)
DEPEND="
	dev-db/sqlite:3
	dev-libs/glib:2
	>=dev-libs/libstrophe-0.12.3:=
	net-misc/curl
	sys-libs/ncurses:=[unicode(+)]
	sys-libs/readline:=
	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
	gtk? ( x11-libs/gtk+3 )
	omemo? (
		dev-libs/libgcrypt
		net-libs/libsignal-protocol-c
	)
	omemo-qrcode? ( media-gfx/qrencode )
	otr? ( net-libs/libotr )
	python? ( ${PYTHON_DEPS} )
	xscreensaver? (
		x11-libs/libXscrnSaver
		x11-libs/libX11
	)
	libnotify? ( x11-libs/libnotify )
	gpg? ( app-crypt/gpgme:= )
	spellcheck? ( app-text/enchant )
"
RDEPEND="${DEPEND}"
BDEPEND=""

IUSE="libnotify omemo omemo-qrcode otr gpg test xscreensaver python gtk gdk-pixbuf spellcheck plugins"

REQUIRED_USE="
	omemo-qrcode? ( omemo )
	python? ( ${PYTHON_REQUIRED_USE} )
"

RESTRICT="mirror"

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_configure() {
	# [net-im/profanity::gentoo] lto-type-mismatch in tests
	filter-lto

	local emesonargs=(
		$(meson_feature libnotify notifications)
		$(meson_feature omemo)
		$(meson_feature omemo-qrcode)
		$(meson_feature otr)
		$(meson_feature gpg pgp)
		$(meson_feature xscreensaver)
		$(meson_feature gtk icons-and-clipboard)
		$(meson_feature gdk-pixbuf)
		$(meson_feature spellcheck)
		$(meson_feature plugins c-plugins)
	)

	meson_src_configure
}
src_compile() {
	meson_src_compile
}

src_install() {
	meson_src_install
}