# Copyright 2026 Shin'ya Minazuki
EAPI=8

inherit desktop xdg

DESCRIPTION="Decentralized and secure messenger app (binary)"
HOMEPAGE="https://delta.chat"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="-* ~amd64 ~arm64"

DC_PN="${PN%-bin}"

SRC_URI="
	amd64? ( https://download.delta.chat/desktop/v${PV}/${DC_PN}-${PV}.tar.gz )
	arm64? ( https://download.delta.chat/desktop/v${PV}/${DC_PN}-${PV}-arm64.tar.gz )
"

S="${WORKDIR}"

IUSE="suid"

QA_PREBUILT="*"

RDEPEND="
	app-accessibility/at-spi2-core:2[X]
	dev-libs/expat
	dev-libs/fribidi
	dev-libs/glib:2
	dev-libs/libpcre2
	dev-libs/libunistring
	dev-libs/nettle
	dev-libs/nspr
	dev-libs/nss
	dev-libs/wayland
	media-gfx/graphite2
	media-libs/alsa-lib
	media-libs/fontconfig
	media-libs/freetype
	media-libs/harfbuzz
	media-libs/libpng
	net-dns/libidn2
	net-libs/gnutls
	net-print/cups
	sys-apps/dbus
	sys-libs/glibc
	virtual/jpeg
	virtual/libudev
	virtual/zlib
	x11-libs/cairo
	x11-libs/gdk-pixbuf:2
	x11-libs/gtk+:3[X]
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXdmcp
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libdrm
	x11-libs/libxcb
	x11-libs/libxkbcommon
	x11-libs/pango
	x11-libs/pixman
"

RESTRICT="mirror strip"

src_install() {
	if use amd64; then
		cd deltachat-desktop-${PV} || die
	elif use arm64; then
		cd deltachat-desktop-${PV}-arm64 || die
	fi

	newicon "${FILESDIR}/deltachat.png" "${DC_PN}.png"

	insinto "/opt/${DC_PN}/locales"
	doins locales/*.pak

	insinto "/opt/${DC_PN}/resources"
	doins resources/app.asar
	insinto "/opt/${DC_PN}/resources/app.asar.unpacked"
	doins -r resources/app.asar.unpacked/html-dist/

	if use amd64; then
		insinto "/opt/${DC_PN}/resources/app.asar.unpacked/node_modules/@deltachat"
		doins -r resources/app.asar.unpacked/node_modules/@deltachat/stdio-rpc-server-linux-x64/
		insinto "/opt/${DC_PN}/resources/app.asar.unpacked/node_modules/@parcel"
		doins -r resources/app.asar.unpacked/node_modules/@parcel/watcher-linux-x64-glibc/
		fperms 0755 "/opt/${DC_PN}/resources/app.asar.unpacked/node_modules/@deltachat/stdio-rpc-server-linux-x64/deltachat-rpc-server"
	elif use arm64; then
		insinto "/opt/${DC_PN}/resources/app.asar.unpacked/node_modules/@deltachat"
		doins -r resources/app.asar.unpacked/node_modules/@deltachat/stdio-rpc-server-linux-arm64/
		insinto "/opt/${DC_PN}/resources/app.asar.unpacked/node_modules/@parcel"
		doins -r resources/app.asar.unpacked/node_modules/@parcel/watcher-linux-arm64-glibc/
		fperms 0755 "/opt/${DC_PN}/resources/app.asar.unpacked/node_modules/@deltachat/stdio-rpc-server-linux-arm64/deltachat-rpc-server"
	fi

	insinto "/opt/${DC_PN}"
	doins *.pak *.bin *.dat
	exeinto "/opt/${DC_PN}"
	doexe *.so *.so.* "${DC_PN}"

	dosym -r "/opt/${DC_PN}/${DC_PN}" "/usr/bin/${DC_PN}"

	make_desktop_entry "${DC_PN} --enable-features=WaylandWindowDecorations --ozone-platform-hint=auto %U" \
		"Delta Chat" "${DC_PN}" "Network;InstantMessaging;" \
		"StartupWMClass=DeltaChat"
}